Excel VBAによるCSVインポート機能の自作（フィールド内の改行も取り込む）

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14

Private Sub Workbook_Open()
    Application.CommandBars("Cell").Reset
    Set newb = Application.CommandBars("Cell").Controls.Add()
    With newb
        .Caption = "csvインポート（横）"
        .OnAction = "CsvImportHorizontal"
        .BeginGroup = True
    End With
    Set newb = Application.CommandBars("Cell").Controls.Add()
    With newb
        .Caption = "csvインポート（縦）"
        .OnAction = "CsvImportVertical"
    End With
End Sub

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104

Option Explicit

Const VERTICAL = 1
Const HORIZONTAL = 2

Const SP = "~~~~~" ' セパレータ
Const EOL = "@@@@@" ' 行端文字
Const DQ = """" ' ダブルクォーテーション

Sub CsvImportHorizontal()
    Call CsvImport(HORIZONTAL)
End Sub

Sub CsvImportVertical()
    Call CsvImport(VERTICAL)
End Sub

Sub CsvImport(hvFlg)
    Dim csvFile, adoSt, buf, lineArr, fieldArr, tpl, i, j, r, c

    On Error GoTo errH

    ' ダウンロードフォルダのCSVファイルを選択
    ChDir CreateObject("Wscript.Shell").SpecialFolders("MyDocuments") & "\..\Downloads\"
    csvFile = Application.GetOpenFilename("CSVファイル(*.csv), *.csv")
    If VarType(csvFile) = vbBoolean Then Exit Sub

    ' ADODBストリームを生成してCSVファイルの内容をバッファに読み込み
    Set adoSt = CreateObject("ADODB.Stream")
    With adoSt
        .Charset = "UTF-8"
        .Type = 2
        .LineSeparator = 10
        .Open
        .LoadFromFile (csvFile)
        buf = .Readtext
        .Close
    End With

    ' バッファ内のセパレータをカンマから別文字に変更する
    buf = rep(buf)

    ' バッファを行単位の配列にする
    buf = Replace(buf, DQ, "")
    buf = Replace(buf, vbCrLf, vbCr)
    buf = Replace(buf, vbLf, EOL)
    buf = Replace(buf, vbCr, vbCrLf)
    lineArr = Split(buf, EOL)
    ' 最終行が空行の場合は除外する
    If lineArr(UBound(lineArr)) = "" Then
        ReDim Preserve lineArr(UBound(lineArr) - 1)
    End If

    ' 行単位の配列をセパレータで分離して２次元配列を作成する
    ReDim fieldArr(UBound(lineArr), UBound(Split(lineArr(0), SP)))
    For i = 0 To UBound(lineArr)
        tpl = Split(lineArr(i), SP)
        For j = 0 To UBound(tpl)
            fieldArr(i, j) = tpl(j)
        Next
    Next

    ' csvインポート（縦）の場合
    If hvFlg = VERTICAL Then
        ' フィールド単位の配列の行要素と列要素を入れ替え
        fieldArr = WorksheetFunction.Transpose(fieldArr)

        ' 貼り付け範囲を取得
        r = UBound(fieldArr, 1)
        c = UBound(fieldArr, 2)

    ' csvインポート（横）の場合
    Else
        ' 貼り付け範囲を取得
        r = UBound(fieldArr, 1) + 1
        c = UBound(fieldArr, 2) + 1

    End If

    ' 貼り付け範囲の書式を文字列に設定
    Range(ActiveCell, ActiveCell.Offset(r - 1, c - 1)).NumberFormatLocal = "@"

    ' フィールド単位の配列をアクティブセルを基点にしてシートに貼り付け
    ActiveCell.Resize(r, c).Value = fieldArr

    Set adoSt = Nothing
    Exit Sub
errH:
    Set adoSt = Nothing
    MsgBox "エラーが発生しました" & vbCrLf & "エラー番号：" & Err.Number & vbCrLf & "エラーの種類：" & Err.Description
End Sub

' セパレータを別文字に置換
Function rep(line)
    Dim regex
    Set regex = CreateObject("vbscript.regexp")
    With regex
        .ignorecase = True
        .Global = True
        .Pattern = ",(?=([^" & DQ & "]*" & DQ & "[^" & DQ & "]*" & DQ & ")*(?![^" & DQ & "]*" & DQ & "))"
        rep = .Replace(line, SP)
    End With
    Set regex = Nothing
End Function